#!/usr/bin/gnuplot
reset
set output "graf3.eps"
set term postscript eps 16
set function style lines
set grid xtics ytics x2tics y2tics mxtics mytics

# ----------------	----------
# Kalibracia detektora
set title ""
# scales the displayed size of the plot
set xlabel "udaj galvanometra"
set ylabel "skutocna hodnota prudu"

# konstanta umernosti -- maximalna hodnota 
K = 172
# zaciatok -- vid datovy subor (hodnoty y == 0)
A = 169 
# koniec   -- vid datovy subor (hodnoty y == 0)
B = 191
# stred

# vzdialenost medzi minimami je iba jedna polvlna, preto nie 2pi ale iba pi
hodn(x) =  pi * ((x - A) / (B - A) )

zavislost(x) = K * sin(hodn(x)) * sin(hodn(x))

# Konstanty urcene z regresie y = A*x^2 + B*x + C
a = 0.004129809
b = 0.246177097
c = 3.296179151

kalibracia(x) = a*x*x + b*x + c

plot [0:200] [0:200] \
	"3.dat" using ($5):(zavislost($1)) notitle with lines 1, \
	"3.dat" using ($5):(zavislost($1)) notitle with points 1, \
	kalibracia(x) notitle with lines 2, \
	"3.dat" using ($5):($5) notitle with lines 1 # priamka (teoret.)


# Hodnoty v grafe mozno vygenerovat nasledujucim prikazom: (awk rulezz...!!! :-)) )
#
#  awk 'BEGIN {pi=3.1415926535 ; A = 169; B = 191; K=172; } function hodn(x){ return  pi * ((x - A) / (B - A) ) } function zavislost(x){ return K * sin(hodn(x)) * sin(hodn(x))}    /^$/ {next}  ! /^[#     ]/ { print $5 " " zavislost($1) }' 3.dat |sort -g -u


# vim: ft=gnuplot